Mad DJNZ Hacks

[thepenguin77]

I was looking through starfox when I saw some code that used DJNZ in an unconventional way, this made me think about how useful it is, so here are some things I just thought of.

On this first one, you're going to say, "well duh," but I bet you don't do it.

Let's say you want to see if A==1:

Code: Select All | Copy To Clipboard

1 2 3

dec a jr nz, AWasnt1

You could replace it with this for only 1 extra t-state:

Code: Select All | Copy To Clipboard

1 2 3

ld b, a djnz AWasnt1

One benefit of this is that you don't destroy A. Now before you start complaining about that 1 t-state, just remember, if you manage to put your result into B rather than A, this routine becomes 3 t-states faster.


Here is another common code structure that I run into a lot:

Code: Select All | Copy To Clipboard

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24

ld a, (hl) dec a jr nz, not1 ... jr final not1: dec a jr nz, not2 ... jr final not2: dec a jr nz, not3 ... jr final not3: dec a jr nz, not4 ... jr final not4: ... final:

Why not replace it with this, which is both faster and smaller (you don't need the jumps if you can leave b at 0):

Code: Select All | Copy To Clipboard

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19

ld b, (hl) djnz not1 ... not1: djnz not2 ... not2: djnz not3 ... not3: djnz not4 ... not4: djnz not5 ... not5: final:

Finally, this one is a bit more of a stretch, but you can use B as a flag byte, take for instance this byte plotter:

Code: Select All | Copy To Clipboard

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35

;###################################### ;plot a byte ;a = byte ;b = inverse 1 = yes, 0 = no ;de = xy plotAByte: ld c, d ld d, 0 ld h, d ld l, e add hl, de add hl, de add hl, hl add hl, hl srl c srl c srl c ld e, c add hl, de ld de, plotSScreen add hl, de djnz inversing or (hl) ld (hl), a ret inversing: cpl and (hl) ld (hl), a ret

Also, while it's not a new idea today, I have used DJNZ in weird ways before, I typically do it when unpacking bytes from storage. This routine is from zStart and pulls a name out of storage from 6 bytes to 8 bytes. I use B as a bit counter.

Code: Select All | Copy To Clipboard

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23

pop hl ld ix, op1+1 ld bc, 8*256+6 ld d, 8 xor a unpackNameLoop: rr (hl) rra djnz notNextUnpackByte inc hl ld b, 8 notNextUnpackByte: dec c jr nz, unpackNameLoop ld c, 6 rra rra ld (ix), a inc ix xor a dec d jr nz, unpackNameLoop

[boot2490]

What
seems cool though

[ralphdspam]

Why not replace it with this, which is both faster and smaller (you don't need the jumps if you can leave b at 0):

Code: Select All | Copy To Clipboard

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19

ld b, (hl) djnz not1 ... not1: djnz not2 ... not2: djnz not3 ... not3: djnz not4 ... not4: djnz not5 ... not5: final:

Wow!  That's great stuff!  
Plus you can keep your original value unchanged in A.  

[Xeda112358]

I use djnz to jump forward very often, actually, and it is a trick I figured out and exploited when I created my first asm library all the way up to BatLib :) I even made a note of it in my opcode chart:

DJNZ * decrements B. If B is   not 0, it pretends to be a jr. If B is 0, the code continues. This is mostly used for loops because it uses only 2 bytes, so * is usually negative. Because of this, people seem to forget that you can jump forward with this. :P   

EDIT: and I use it for things like selecting a sprite method to draw with, rectangle method, pixel plotting method, et cetera.

[calc84maniac]

Another DJNZ hack is that you can use DJNZ $+2 to decrease B without affecting any flags. It's 4-9 cycles slower than normal DEC B, though.

[thepenguin77]

Brilliant

(And useless in 99% of cases)

[Xeda112358]

It is one of those things that may not be used for a long time, but when it happens, somebody is going to feel special

[Jonius7]

That looks very nice, the djnz bundles dec, jr, nz nicely, saving space and adding efficiency. Could be useful, +1.

[chickendude]

It's amazing how creative you all are. For the djnz list i usually just use a jump table and maybe push a return value onto the stack, but that looks like it'd be smaller (if not faster), though you'd have to be careful with 'b'.

[All_¥our_Bass]

 ld b,0
for_loop:
;stuff here
 djnz for_loop
;will repeat 256 times

[Builderboy]

I think the best DJNZ is to ONLY use DJNZ I was reading about Single Instruction Set Computers and learned that using only DJNZ you can produce a turring complete language!

[All_¥our_Bass]

I think the best DJNZ is to ONLY use DJNZ I was reading about Single Instruction Set Computers and learned that using only DJNZ you can produce a turring complete language!

Mind = Blown

[Jonius7]

What does turring complete language mean? especially the turring part.
Do you mean Turing, as for example, the Turing test?

[Builderboy]

Turing Completeness is a computer science term referring to the ability of a language to complete problems.  If a language is Turing Complete, it is able to solve any problem a Turing computer could solve.